Asked By:
Crazy Girl
in
Bilgisayar & İnternet
-
552 days ago
ahmetinejat's Answer
Merhaba,
Buradaki notlar Access ve Excel'de nasil fonksiyon olusturulabilecegini bir ornek yardimiyla anlatmaktadir. Ornek olarak kullanilan fonksiyon, rakkamla yazilan sayiyi metin haline donusturur ve sonucu fonksiyonun degeri olarak dondurur.
Ornegin:
A=Sayiyi_Metne_Cevir(342865)
seklinde bir esitlik yazarsak A'nin degeri "üçyüzkırkikibinsekizyüzaltmışbeş" olur.
Bu fonksiyonu, hem fonksiyon yazimiyla ilgilenenlere bir ornek olsun, hem de bircok yerde kullanabilecegimiz pratik bir cozum olsun diye veriyorum. Bu fonksiyonu Excel'de ve Access'de kullanmamiz mumkundur. Burada yazilanlar daha once Excel ve Access kullananlarin rahat uygulayabilecegi duzeydedir. Eger bu programlari fazla bilmiyorsaniz bile talimatlari takip ederseniz yapabilirsiniz.
A) FONKSIYON HAKKINDA BILGI
Bu fonksiyon, VBA (Visual Basic for Applications) adi verilen Visual Basic'le tamamen uyumlu bir programlama dili kullanilarak yazilmistir. Su an 15 haneli sayilari sorunsuz olarak metin haline donusturebilmektedir. Algoritma olarak sonsuz buyuklukte sayilari metne cevirmesi mumkundur (Bunun icin dongu icindeki select case bolumune yeni satirlar eklemelisiniz. Ornegin:
Case 7: S_Metin = UcHane(S_Rakkam Mod 1000) & "binkatrilyon" & S_Metin
gibi.)
Fonksiyonun su an 15 haneyle sinirli olmasinin sebebi Access ve Excel'in 15 haneden buyuk sayilari yuvarlamadan kaydedememesidir. Access ve Excel bu meseleyi hallederse fonksiyonu daha buyuksayilar için de kullanabilirsiniz.
Fonksiyon icinde mod komutu kullanilmaktadir. Mod komutu sadece long tipindeki degiskenlerle (2 milyardan kucuk tam sayilarla) calistigi icin, sayimiz 9 haneleri sayilara bolunerek isleme sokulmaktadir.
Fonksiyon ic hesaplamalarinda kullanmak icin UcHane adinda ikinci bir fonksiyon da kullanmaktadır. Bu fonksiyon kendisine verilen uc heneli sayiyi metne cevirir. Yani burada aslinda iki tane fonksiyon vardır.
B) FONKSIYONUN EXCEL'DE KULLANIMI
i) Excel'i acin.
ii) Menuden Tools -> Makro -> Visual Basic Editor secenegini secin. Visual Basic Editor sayfasi acilacaktir.
iii) Bos bir modul sayfasi eklemek icin menuden Insert -> Modul secenegini secin.
iv) Acilan yeni modul sayfasinin ilk satirinda buyuk ihtimalle Option Explicit ifadesi yaziyor olacaktir. Bu ifadenin altina asagida verilen fonksiyonlari yazin. (Buradan kopyalayip yapistirabilirsiniz)
v) Menuden File -> Save secilerek veya uzerinde disket resmi olan save (kaydet) dugmesine basarak su ana kadar yaptiklarinizi kaydediniz. Visual Basic Editor penceresini kapatiniz.
vi) Excel sheet'ine (sayfasina) donelim ve bir ornek yapalim. A1 kutusuna 7436326 yaziniz. A2 kutusuna da =Sayiyi_Metne_Cevir(A1) yaziniz. A2 kutusunda yedimilyondörtyuzotuzaltibinüçyüzyirmialti yazdigini goreceksiniz.
vii) Bu fonksiyonu su sekilde de kullanabilirsiniz. Bos bir kutu (Cell) seciliyken menuden Insert -> Function secenegini seciniz. Acilan pencerenin Function Category bolumunden User Defined 'i seciniz. Function Name bolumunde bizim yazdigimiz fonksiyonlar gorunecektir. Sayiyi_Metne_Cevir'in ustune cift tiklayiniz veya secip OK tusuna basiniz. Acilan pencerede Sayi bolumune A1 yaziniz veya mouse'la, Sayi bilgisini alacaginiz kutuya tiklayiniz. OK tusuna basiniz.
C) FONKSIYONUN ACCESS'DE KULLANIMI
i) Bos bir Access dosyasi aciniz veya bu fonksiyonu kullanmayi dusundugunuz Access dosyasini (mdb dosyasini) aciniz.
ii) Module bolumune geciniz ve New (yeni) tusuna basiniz. Veya menuden Insert -> Module secenegini seciniz. Yeni bir modul sayfasi acilacaktir.
iii) Yeni modul sayfasinda buyuk ihtimalle
Option Compare Database
Option Explicit
ifadelerini goreceksiniz. Bunlarin altina asagidaki fonksiyonlari yaziniz veya buradan fonksiyonlari kopyalayip, modul sayfasina yapistiriniz.
iv) Menuden File -> Save (kaydet) secenegini secerek veya uzerinde disket resmi olan save (kaydet) ikonuna basarak yazdiginiz modulu kaydediniz. Fonksiyonumuz artik kullanima hazirdir. Modul penceresini kapatabilirsiniz.
v) Form icinde bunu su sekilde kullanabiliriz. Yeni bir form olusturalim. Bu forma iki tane text box (metin kutusu) koyalim. Birinci metin kutusunun uzerine cift tiklayarak property (ozellikler) penceresini acalim. Bu pencerenin other (diger) sayfasindaki Name (ad) bolumune SayiRakkamla yazarak bu kutunun ismini SayiRakkamla yapmis olalim.
Ikınci kutuya cift tiklayarak bu kutunun property (ozellikler) penceresini acalim. Bu pencerenin Data (veri) sayfasindaki Control Source (veri kaynagi) bolumune =Sayiyi_Metne_Cevir(SayiRakkamla) yazalim. Form calisinca birinci kutuya yazdigimiz sayi metine donusturulecek ve sonuc ikinci kutuda gorunecektir.
Ayni mantikla bu fonksiyonu raporlarda, diger modullerde, sorgularda kullanabilirsiniz.
Access'de modul kullanimi hakkinda bilginiz yoksa veya bu konuyla ilgili baslangic bilgilerini ogrenmek isterseniz, Access bolumunde yer alan Access'de Programlamaya Giris adli dersi okumanizi tavsiye ederim.
D) FONKSİYONLARIN METNI
Burada gordugunuz kodlari yukarida belirtilen bolumlere yaziniz veya buradan kopyalayip, gereken yere yapistiriniz. Bu kodlar Access ve Excel'de denenmistir, duzgun calismaktadir.
Public Function Sayiyi_Metne_Cevir(Sayi As Double) As String
On Error GoTo Hata_Olustu_Satiri
'Bu fonksiyon rakkam kullanilarak yazilan sayiyi metne cevirir.
'Sonuc Sayiyi_Metne_Cevir fonksiyonunun degeri olarak geri doner.
'Bu fonksiyon kesirli sayilari, yuvarladiktan sonra isleme sokar.
Dim S_Metin As String, Isaret As String
Dim S_Rakkam As Double, M_Rakkam As Double
Dim Sayac As Byte
'Fonksiyon tam sayilar icin calistigindan
'Sayi yuvarlanarak tam sayiya cevriliyor
Sayi = Round(Sayi)
Select Case Sayi
Case 0:
'Sayi sifir. Fonksiyon degerini sifir dondur, fonksiyondan cik
Sayiyi_Metne_Cevir = "sıfır"
GoTo Cikis_Satiri
Case Is < 0:
'Sayi negatif. Isareti degerini eksi yap. Sayiyi pozitife cevir, isleme devam et
Isaret = "eksi"
Sayi = -1 * Sayi
Case Is > 0:
'Sayi pozitif. Isleme devam et
Isaret = ""
End Select
'Islemlerde mod fonksiyonu kullanilacaginda overflow u engellemek icin
'Sayi 9 haneli sayilara bolunerek isleme sokuluyor
S_Rakkam = Sayi - 1000000000 * Round(0.000000001 * Sayi, 0)
If S_Rakkam < 0 Then
S_Rakkam = S_Rakkam + 1000000000
End If
M_Rakkam = S_Rakkam
'Donguye baslamadan once Sayac degerini 1'e esitle
'Sayac, sagdan itibaren kacinci 3 hanenin isleme girdigini gosterir.
Sayac = 1
Do While Sayi > 0
If (S_Rakkam Mod 1000) > 0 Then
Select Case Sayac
Case 1: S_Metin = UcHane(S_Rakkam Mod 1000)
Case 2:
'Binler bolumunde ozel bir durum var. Eger bu uc hane 001 seklinde olursa
'birbin ifadesi kullanilmadigi icin bu durumda sadece bin yazdiracagiz
If (S_Rakkam Mod 1000) = 1 Then
S_Metin = "bin" & S_Metin
Else
S_Metin = UcHane(S_Rakkam Mod 1000) & "bin" & S_Metin
End If
Case 3: S_Metin = UcHane(S_Rakkam Mod 1000) & "milyon" & S_Metin
Case 4: S_Metin = UcHane(S_Rakkam Mod 1000) & "milyar" & S_Metin
Case 5: S_Metin = UcHane(S_Rakkam Mod 1000) & "trilyon" & S_Metin
Case 6: S_Metin = UcHane(S_Rakkam Mod 1000) & "katrilyon" & S_Metin
'Bu bolumu ayni mantikla devam ettitmek mumkun ama Access
'15 haneden buyuk sayilarda yuvarlama yapacagi icin sonuc dogru olmaz
'Bu bolum algoritma olarak dogrudur.
Case Else
End Select
End If
'Isi biten sagdaki uc hane siliniyor
S_Rakkam = (S_Rakkam - (S_Rakkam Mod 1000)) / 1000
'Eger sag taraftaki dokuz hanenin islemi bittiyse
'sonraki dokuz hane S_Rakkam degerine esitleniyor
If Sayac Mod 3 = 0 Then
Sayi = (Sayi - M_Rakkam) / 1000000000
S_Rakkam = Sayi - 1000000000 * Round(0.000000001 * Sayi, 0)
If S_Rakkam < 0 Then
S_Rakkam = S_Rakkam + 1000000000
End If
M_Rakkam = S_Rakkam
End If
Sayac = Sayac + 1
Loop
Sayiyi_Metne_Cevir = Isaret & S_Metin
Cikis_Satiri:
Exit Function
Hata_Olustu_Satiri:
MsgBox Error$
Resume Cikis_Satiri
End Function
Public Function UcHane(UcHaneSayi As Integer) As String
On Error GoTo Hata_Olustu_Satiri
'Bu fonksiyon rakkam kullanilarak yazilan 3 haneli sayiyi
'metne cevirir. Sonuc UcHane fonksiyonunun degeri
'olarak geri doner
Dim UcHaneMetin As String
Select Case UcHaneSayi Mod 10
Case 1: UcHaneMetin = "bir"
Case 2: UcHaneMetin = "iki"
Case 3: UcHaneMetin = "üç"
Case 4: UcHaneMetin = "dört"
Case 5: UcHaneMetin = "beş"
Case 6: UcHaneMetin = "altı"
Case 7: UcHaneMetin = "yedi"
Case 8: UcHaneMetin = "sekiz"
Case 9: UcHaneMetin = "dokuz"
Case Else
End Select
'Sagdaki rakkam atiliyor. Sayi iki haneye dusuyor.
UcHaneSayi = (UcHaneSayi - (UcHaneSayi Mod 10)) / 10
Select Case UcHaneSayi Mod 10
Case 1: UcHaneMetin = "on" & UcHaneMetin
Case 2: UcHaneMetin = "yirmi" & UcHaneMetin
Case 3: UcHaneMetin = "otuz" & UcHaneMetin
Case 4: UcHaneMetin = "kırk" & UcHaneMetin
Case 5: UcHaneMetin = "elli" & UcHaneMetin
Case 6: UcHaneMetin = "altmış" & UcHaneMetin
Case 7: UcHaneMetin = "yetmiş" & UcHaneMetin
Case 8: UcHaneMetin = "seksen" & UcHaneMetin
Case 9: UcHaneMetin = "doksan" & UcHaneMetin
Case Else
End Select
'Sagdaki rakkam atiliyor. Sayi bir haneye dusuyor.
UcHaneSayi = (UcHaneSayi - (UcHaneSayi Mod 10)) / 10
Select Case UcHaneSayi
Case 1: UcHaneMetin = "yüz" & UcHaneMetin
Case 2: UcHaneMetin = "ikiyüz" & UcHaneMetin
Case 3: UcHaneMetin = "üçyüz" & UcHaneMetin
Case 4: UcHaneMetin = "dörtyüz" & UcHaneMetin
Case 5: UcHaneMetin = "besyüz" & UcHaneMetin
Case 6: UcHaneMetin = "altıyüz" & UcHaneMetin
Case 7: UcHaneMetin = "yediyüz" & UcHaneMetin
Case 8: UcHaneMetin = "sekizyüz" & UcHaneMetin
Case 9: UcHaneMetin = "dokuzyüz" & UcHaneMetin
Case Else
End Select
UcHane = UcHaneMetin
Cikis_Satiri:
Exit Function
Hata_Olustu_Satiri:
MsgBox Error$
Resume Cikis_Satiri
End Function
Answered
552 days ago |
Read Comments (1)
Read answer
